Re: [MSAccessProfessionals] Access 2006 Simple question

Carol - If you want to remove all the subdata sheets in a project, You can run this function:

 

Public Function dev_TbrTurnOffSubDataSheets()

'Purpose  : Access sets all tables' SubDataSheets to Auto which slows up loading time.

'           This function will set the property to [none].

'DateTime : 1/14/2004 09:20

'Author   : Bill Mosca

    Dim db As DAO.Database

    Dim prop As DAO.Property

    Dim propName As String, propVal As String

    Dim propType As Integer, i As Integer

 

    On Error Resume Next

 

    Set db = CurrentDb

 

    propName = "SubDataSheetName"

    propType = 10

    propVal = "[NONE]"

 

 

    For i = 0 To db.TableDefs.Count - 1

 

        If (db.TableDefs(i).Attributes And dbSystemObject) = 0 Then

 

            If db.TableDefs(i).Properties(propName).Value <> propVal Then

                db.TableDefs(i).Properties(propName).Value = propVal

            End If

 

            If Err.Number = 3270 Then

                Err.Clear

                Set prop = db.TableDefs(i).CreateProperty(propName)

                prop.Type = propType

                prop.Value = propVal

                db.TableDefs(i).Properties.Append prop

            Else

                If Err.Number <> 0 Then

                    Resume Next

                End If

            End If

 

        End If

    Next i

 

    MsgBox "The " & propName & _

            " value for all non-system tables has been updated to " & propVal & "."

 

    Set prop = Nothing

    Set db = Nothing

 

End Function

More developers' functions can be found in our  Files > 3_Code Snippets > basDevToolBar.txt

On Sun, Mar 28, 2021 at 10:15 AM, <cash.ghwa@gmail.com> wrote:

THANK YOU ALL FOR YOUR HELP ON THIS.  AT LEAST NOW A HAVE A PROPER TERM FOR IT AND WHEN I GO TO SET IT UP IN A DIFFERENT DATABASE,  I'LL AT LEAST BE OON THE RIGHT TRACK.   tHE MAIN FILE I USE IT WITH HAS 12,500 RECORDS.  AND IT IS A PERSONAL USE FILE, SO PROCESSING SPEED ISN'T AN ISSUE.

 

 

YOU GUYS AND GAL ARE GREAT!

 

 

Sent from Mail for Windows 10

 

From: cash.ghwa@gmail.com
Sent: Saturday, March 27, 2021 3:14 PM
To: MSAccessProfessionals@groups.io
Subject: Access 2006 Simple question

 

Hi.

 

Seems the only time I ask a question is when I have a senior moment.   I wrote a basic query years ago.. When I get my results, I somehow connected the result records back to the main database. They can be displayed by clicking on the "+" that shows up to the left of the record.  How did I do that? I tried creating a new query but can not get it.  The original one has the query "related" to the main database by the "Itemnbr ".

 

The main database (stripped down version) contains: itemnbr, description, cost, sell, purchasedate, selldate.  Nothing fancy.  The query table only contains: itemnbr, selldate.  When I run the query I can click on the result record by using the "+" to recall more details about the item if needed.

 

Simple!!   Not anymore…… HELP!

 

I have another senior moment issue, but can wait on than one….I'll try figuring it out for a bit longer before I give up.

 

Thank you.

 

Carol Higbee

 

 

Sent from Mail for Windows 10

 

 

 
--

Regards,

Bill Mosca, Founder - MS_Access_Professionals

Microsoft Office Access MVP 2010-2016

My nothing-to-do-with-Access blog

http://wrmosca.wordpress.com

 

_._,_._,_

---

Groups.io Links:

You receive all messages sent to this group.

View/Reply Online (#115943) | Reply To Group | Reply To Sender | Mute This Topic | New Topic
Your Subscription | Contact Group Owner | Unsubscribe [sugeng.panjalu.access@blogger.com]

_._,_._,_